/[pcre]/code/trunk/configure.ac
ViewVC logotype

Contents of /code/trunk/configure.ac

Parent Directory Parent Directory | Revision Log Revision Log


Revision 481 - (show annotations)
Sun Jan 3 17:45:53 2010 UTC (5 years, 5 months ago) by ph10
File size: 26629 byte(s)
Error occurred while calculating annotation data.
Forbid 08 and 09 as minor version numbers.
1 dnl Process this file with autoconf to produce a configure script.
2
3 dnl NOTE FOR MAINTAINERS: Do not use minor version numbers 08 or 09 because
4 dnl the leading zeros may cause them to be treated as invalid octal constants
5 dnl if a PCRE user writes code that uses PCRE_MINOR as a number. There is now
6 dnl a check further down that throws an error if 08 or 09 are used.
7
8 dnl The PCRE_PRERELEASE feature is for identifying release candidates. It might
9 dnl be defined as -RC2, for example. For real releases, it should be empty.
10
11 m4_define(pcre_major, [8])
12 m4_define(pcre_minor, [01])
13 m4_define(pcre_prerelease, [-RC1])
14 m4_define(pcre_date, [2010-01-02])
15
16 # Libtool shared library interface versions (current:revision:age)
17 m4_define(libpcre_version, [0:1:0])
18 m4_define(libpcreposix_version, [0:0:0])
19 m4_define(libpcrecpp_version, [0:0:0])
20
21 AC_PREREQ(2.57)
22 AC_INIT(PCRE, pcre_major.pcre_minor[]pcre_prerelease, , pcre)
23 AC_CONFIG_SRCDIR([pcre.h.in])
24 AM_INIT_AUTOMAKE([dist-bzip2 dist-zip])
25 AC_CONFIG_HEADERS(config.h)
26
27 # This was added at the suggestion of libtoolize (03-Jan-10)
28 AC_CONFIG_MACRO_DIR([m4])
29
30 # The default CFLAGS and CXXFLAGS in Autoconf are "-g -O2" for gcc and just
31 # "-g" for any other compiler. There doesn't seem to be a standard way of
32 # getting rid of the -g (which I don't think is needed for a production
33 # library). This fudge seems to achieve the necessary. First, we remember the
34 # externally set values of CFLAGS and CXXFLAGS. Then call the AC_PROG_CC and
35 # AC_PROG_CXX macros to find the compilers - if CFLAGS and CXXFLAGS are not
36 # set, they will be set to Autoconf's defaults. Afterwards, if the original
37 # values were not set, remove the -g from the Autoconf defaults.
38 # (PH 02-May-07)
39
40 remember_set_CFLAGS="$CFLAGS"
41 remember_set_CXXFLAGS="$CXXFLAGS"
42
43 AC_PROG_CC
44 AC_PROG_CXX
45
46 if test "x$remember_set_CFLAGS" = "x"
47 then
48 if test "$CFLAGS" = "-g -O2"
49 then
50 CFLAGS="-O2"
51 elif test "$CFLAGS" = "-g"
52 then
53 CFLAGS=""
54 fi
55 fi
56
57 if test "x$remember_set_CXXFLAGS" = "x"
58 then
59 if test "$CXXFLAGS" = "-g -O2"
60 then
61 CXXFLAGS="-O2"
62 elif test "$CXXFLAGS" = "-g"
63 then
64 CXXFLAGS=""
65 fi
66 fi
67
68 # AC_PROG_CXX will return "g++" even if no c++ compiler is installed.
69 # Check for that case, and just disable c++ code if g++ doesn't run.
70 AC_LANG_PUSH(C++)
71 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([],[]),, CXX=""; CXXCP=""; CXXFLAGS="")
72 AC_LANG_POP
73
74 # Check for a 64-bit integer type
75 AC_TYPE_INT64_T
76
77 AC_PROG_INSTALL
78 AC_LIBTOOL_WIN32_DLL
79 AC_PROG_LIBTOOL
80 AC_PROG_LN_S
81
82 PCRE_MAJOR="pcre_major"
83 PCRE_MINOR="pcre_minor"
84 PCRE_PRERELEASE="pcre_prerelease"
85 PCRE_DATE="pcre_date"
86
87 if test "$PCRE_MINOR" = "08" -o "$PCRE_MINOR" = "09"
88 then
89 echo "***"
90 echo "*** Minor version number $PCRE_MINOR must not be used. ***"
91 echo "*** Use only 01 to 07 or 10 onwards, to avoid octal issues. ***"
92 echo "***"
93 exit 1
94 fi
95
96 AC_SUBST(PCRE_MAJOR)
97 AC_SUBST(PCRE_MINOR)
98 AC_SUBST(PCRE_PRERELEASE)
99 AC_SUBST(PCRE_DATE)
100
101 # Set a more sensible default value for $(htmldir).
102 if test "x$htmldir" = 'x${docdir}'
103 then
104 htmldir='${docdir}/html'
105 fi
106
107 # Handle --disable-cpp
108 AC_ARG_ENABLE(cpp,
109 AS_HELP_STRING([--disable-cpp],
110 [disable C++ support]),
111 , enable_cpp=yes)
112
113 # Handle --enable-rebuild-chartables
114 AC_ARG_ENABLE(rebuild-chartables,
115 AS_HELP_STRING([--enable-rebuild-chartables],
116 [rebuild character tables in current locale]),
117 , enable_rebuild_chartables=no)
118
119 # Handle --enable-utf8 (disabled by default)
120 AC_ARG_ENABLE(utf8,
121 AS_HELP_STRING([--enable-utf8],
122 [enable UTF-8 support (incompatible with --enable-ebcdic)]),
123 , enable_utf8=unset)
124
125 # Handle --enable-unicode-properties
126 AC_ARG_ENABLE(unicode-properties,
127 AS_HELP_STRING([--enable-unicode-properties],
128 [enable Unicode properties support (implies --enable-utf8)]),
129 , enable_unicode_properties=no)
130
131 # Handle --enable-newline=NL
132 dnl AC_ARG_ENABLE(newline,
133 dnl AS_HELP_STRING([--enable-newline=NL],
134 dnl [use NL as newline (lf, cr, crlf, anycrlf, any; default=lf)]),
135 dnl , enable_newline=lf)
136
137 # Separate newline options
138 ac_pcre_newline=lf
139 AC_ARG_ENABLE(newline-is-cr,
140 AS_HELP_STRING([--enable-newline-is-cr],
141 [use CR as newline character]),
142 ac_pcre_newline=cr)
143 AC_ARG_ENABLE(newline-is-lf,
144 AS_HELP_STRING([--enable-newline-is-lf],
145 [use LF as newline character (default)]),
146 ac_pcre_newline=lf)
147 AC_ARG_ENABLE(newline-is-crlf,
148 AS_HELP_STRING([--enable-newline-is-crlf],
149 [use CRLF as newline sequence]),
150 ac_pcre_newline=crlf)
151 AC_ARG_ENABLE(newline-is-anycrlf,
152 AS_HELP_STRING([--enable-newline-is-anycrlf],
153 [use CR, LF, or CRLF as newline sequence]),
154 ac_pcre_newline=anycrlf)
155 AC_ARG_ENABLE(newline-is-any,
156 AS_HELP_STRING([--enable-newline-is-any],
157 [use any valid Unicode newline sequence]),
158 ac_pcre_newline=any)
159 enable_newline="$ac_pcre_newline"
160
161 # Handle --enable-bsr-anycrlf
162 AC_ARG_ENABLE(bsr-anycrlf,
163 AS_HELP_STRING([--enable-bsr-anycrlf],
164 [\R matches only CR, LF, CRLF by default]),
165 , enable_bsr_anycrlf=no)
166
167 # Handle --enable-ebcdic
168 AC_ARG_ENABLE(ebcdic,
169 AS_HELP_STRING([--enable-ebcdic],
170 [assume EBCDIC coding rather than ASCII; incompatible with --enable-utf8; use only in (uncommon) EBCDIC environments; it implies --enable-rebuild-chartables]),
171 , enable_ebcdic=no)
172
173 # Handle --disable-stack-for-recursion
174 AC_ARG_ENABLE(stack-for-recursion,
175 AS_HELP_STRING([--disable-stack-for-recursion],
176 [don't use stack recursion when matching]),
177 , enable_stack_for_recursion=yes)
178
179 # Handle --enable-pcregrep-libz
180 AC_ARG_ENABLE(pcregrep-libz,
181 AS_HELP_STRING([--enable-pcregrep-libz],
182 [link pcregrep with libz to handle .gz files]),
183 , enable_pcregrep_libz=no)
184
185 # Handle --enable-pcregrep-libbz2
186 AC_ARG_ENABLE(pcregrep-libbz2,
187 AS_HELP_STRING([--enable-pcregrep-libbz2],
188 [link pcregrep with libbz2 to handle .bz2 files]),
189 , enable_pcregrep_libbz2=no)
190
191 # Handle --enable-pcretest-libreadline
192 AC_ARG_ENABLE(pcretest-libreadline,
193 AS_HELP_STRING([--enable-pcretest-libreadline],
194 [link pcretest with libreadline]),
195 , enable_pcretest_libreadline=no)
196
197 # Handle --with-posix-malloc-threshold=NBYTES
198 AC_ARG_WITH(posix-malloc-threshold,
199 AS_HELP_STRING([--with-posix-malloc-threshold=NBYTES],
200 [threshold for POSIX malloc usage (default=10)]),
201 , with_posix_malloc_threshold=10)
202
203 # Handle --with-link-size=N
204 AC_ARG_WITH(link-size,
205 AS_HELP_STRING([--with-link-size=N],
206 [internal link size (2, 3, or 4 allowed; default=2)]),
207 , with_link_size=2)
208
209 # Handle --with-match-limit=N
210 AC_ARG_WITH(match-limit,
211 AS_HELP_STRING([--with-match-limit=N],
212 [default limit on internal looping (default=10000000)]),
213 , with_match_limit=10000000)
214
215 # Handle --with-match-limit_recursion=N
216 #
217 # Note: In config.h, the default is to define MATCH_LIMIT_RECURSION
218 # symbolically as MATCH_LIMIT, which in turn is defined to be some numeric
219 # value (e.g. 10000000). MATCH_LIMIT_RECURSION can otherwise be set to some
220 # different numeric value (or even the same numeric value as MATCH_LIMIT,
221 # though no longer defined in terms of the latter).
222 #
223 AC_ARG_WITH(match-limit-recursion,
224 AS_HELP_STRING([--with-match-limit-recursion=N],
225 [default limit on internal recursion (default=MATCH_LIMIT)]),
226 , with_match_limit_recursion=MATCH_LIMIT)
227
228 # Make sure that if enable_unicode_properties was set, that UTF-8 support
229 # is enabled.
230 #
231 if test "x$enable_unicode_properties" = "xyes"
232 then
233 if test "x$enable_utf8" = "xno"
234 then
235 AC_MSG_ERROR([support for Unicode properties requires UTF-8 support])
236 fi
237 enable_utf8=yes
238 fi
239
240 if test "x$enable_utf8" = "xunset"
241 then
242 enable_utf8=no
243 fi
244
245 # Make sure that if enable_ebcdic is set, rebuild_chartables is also enabled.
246 # Also check that UTF-8 support is not requested, because PCRE cannot handle
247 # EBCDIC and UTF-8 in the same build. To do so it would need to use different
248 # character constants depending on the mode.
249 #
250 if test "x$enable_ebcdic" = "xyes"
251 then
252 enable_rebuild_chartables=yes
253 if test "x$enable_utf8" = "xyes"
254 then
255 AC_MSG_ERROR([support for EBCDIC and UTF-8 cannot be enabled at the same time])
256 fi
257 fi
258
259 # Convert the newline identifier into the appropriate integer value.
260 case "$enable_newline" in
261 lf) ac_pcre_newline_value=10 ;;
262 cr) ac_pcre_newline_value=13 ;;
263 crlf) ac_pcre_newline_value=3338 ;;
264 anycrlf) ac_pcre_newline_value=-2 ;;
265 any) ac_pcre_newline_value=-1 ;;
266 *)
267 AC_MSG_ERROR([invalid argument \"$enable_newline\" to --enable-newline option])
268 ;;
269 esac
270
271 # Check argument to --with-link-size
272 case "$with_link_size" in
273 2|3|4) ;;
274 *)
275 AC_MSG_ERROR([invalid argument \"$with_link_size\" to --with-link-size option])
276 ;;
277 esac
278
279 AH_TOP([
280 /* On Unix-like systems config.h.in is converted by "configure" into config.h.
281 Some other environments also support the use of "configure". PCRE is written in
282 Standard C, but there are a few non-standard things it can cope with, allowing
283 it to run on SunOS4 and other "close to standard" systems.
284
285 If you are going to build PCRE "by hand" on a system without "configure" you
286 should copy the distributed config.h.generic to config.h, and then set up the
287 macro definitions the way you need them. You must then add -DHAVE_CONFIG_H to
288 all of your compile commands, so that config.h is included at the start of
289 every source.
290
291 Alternatively, you can avoid editing by using -D on the compiler command line
292 to set the macro values. In this case, you do not have to set -DHAVE_CONFIG_H.
293
294 PCRE uses memmove() if HAVE_MEMMOVE is set to 1; otherwise it uses bcopy() if
295 HAVE_BCOPY is set to 1. If your system has neither bcopy() nor memmove(), set
296 them both to 0; an emulation function will be used. */])
297
298 # Checks for header files.
299 AC_HEADER_STDC
300 AC_CHECK_HEADERS(limits.h sys/types.h sys/stat.h dirent.h windows.h)
301
302 # The files below are C++ header files.
303 pcre_have_type_traits="0"
304 pcre_have_bits_type_traits="0"
305 if test "x$enable_cpp" = "xyes" -a -n "$CXX"
306 then
307 AC_LANG_PUSH(C++)
308
309 # Older versions of pcre defined pcrecpp::no_arg, but in new versions
310 # it's called pcrecpp::RE::no_arg. For backwards ABI compatibility,
311 # we want to make one an alias for the other. Different systems do
312 # this in different ways. Some systems, for instance, can do it via
313 # a linker flag: -alias (for os x 10.5) or -i (for os x <=10.4).
314 OLD_LDFLAGS="$LDFLAGS"
315 for flag in "-alias,__ZN7pcrecpp2RE6no_argE,__ZN7pcrecpp6no_argE" \
316 "-i__ZN7pcrecpp6no_argE:__ZN7pcrecpp2RE6no_argE"; do
317 AC_MSG_CHECKING([for alias support in the linker])
318 LDFLAGS="$OLD_LDFLAGS -Wl,$flag"
319 # We try to run the linker with this new ld flag. If the link fails,
320 # we give up and remove the new flag from LDFLAGS.
321 AC_LINK_IFELSE(AC_LANG_PROGRAM([namespace pcrecpp {
322 class RE { static int no_arg; };
323 int RE::no_arg;
324 }],
325 []),
326 [AC_MSG_RESULT([yes]);
327 EXTRA_LIBPCRECPP_LDFLAGS="$EXTRA_LIBPCRECPP_LDFLAGS -Wl,$flag";
328 break;],
329 AC_MSG_RESULT([no]))
330 done
331 LDFLAGS="$OLD_LDFLAGS"
332
333 # We could be more clever here, given we're doing AC_SUBST with this
334 # (eg set a var to be the name of the include file we want). But we're not
335 # so it's easy to change back to 'regular' autoconf vars if we needed to.
336 AC_CHECK_HEADERS(string, [pcre_have_cpp_headers="1"],
337 [pcre_have_cpp_headers="0"])
338 AC_CHECK_HEADERS(bits/type_traits.h, [pcre_have_bits_type_traits="1"],
339 [pcre_have_bits_type_traits="0"])
340 AC_CHECK_HEADERS(type_traits.h, [pcre_have_type_traits="1"],
341 [pcre_have_type_traits="0"])
342
343 AC_LANG_POP
344 fi
345 # Using AC_SUBST eliminates the need to include config.h in a public .h file
346 AC_SUBST(pcre_have_type_traits)
347 AC_SUBST(pcre_have_bits_type_traits)
348
349 # Conditional compilation
350 AM_CONDITIONAL(WITH_PCRE_CPP, test "x$enable_cpp" = "xyes")
351 AM_CONDITIONAL(WITH_REBUILD_CHARTABLES, test "x$enable_rebuild_chartables" = "xyes")
352
353 # Checks for typedefs, structures, and compiler characteristics.
354
355 AC_C_CONST
356 AC_TYPE_SIZE_T
357
358 pcre_have_strotolonglong=0
359 AC_CHECK_FUNCS(strtoq strtoll _strtoi64, [pcre_have_strotolonglong="1"; break])
360 # If we can't convert a string to a long long, pretend we don't even
361 # have a long long.
362 if test $pcre_have_strotolonglong = "0"; then
363 pcre_have_long_long="0"
364 pcre_have_ulong_long="0"
365 else
366 AC_CHECK_TYPES([long long],
367 [pcre_have_long_long="1"],
368 [pcre_have_long_long="0"])
369 AC_CHECK_TYPES([unsigned long long],
370 [pcre_have_ulong_long="1"],
371 [pcre_have_ulong_long="0"])
372 fi
373 AC_SUBST(pcre_have_long_long)
374 AC_SUBST(pcre_have_ulong_long)
375
376 # Checks for library functions.
377
378 AC_CHECK_FUNCS(bcopy memmove strerror)
379
380 # Check for the availability of libz (aka zlib)
381
382 AC_CHECK_HEADERS([zlib.h], [HAVE_ZLIB_H=1])
383 AC_CHECK_LIB([z], [gzopen], [HAVE_LIBZ=1])
384
385 # Check for the availability of libbz2. Originally we just used AC_CHECK_LIB,
386 # as for libz. However, this had the following problem, diagnosed and fixed by
387 # a user:
388 #
389 # - libbz2 uses the Pascal calling convention (WINAPI) for the functions
390 # under Win32.
391 # - The standard autoconf AC_CHECK_LIB fails to include "bzlib.h",
392 # therefore missing the function definition.
393 # - The compiler thus generates a "C" signature for the test function.
394 # - The linker fails to find the "C" function.
395 # - PCRE fails to configure if asked to do so against libbz2.
396 #
397 # Solution:
398 #
399 # - Replace the AC_CHECK_LIB test with a custom test.
400
401 AC_CHECK_HEADERS([bzlib.h], [HAVE_BZLIB_H=1])
402 # Original test
403 # AC_CHECK_LIB([bz2], [BZ2_bzopen], [HAVE_LIBBZ2=1])
404 #
405 # Custom test follows
406
407 AC_MSG_CHECKING([for libbz2])
408 OLD_LIBS="$LIBS"
409 LIBS="$LIBS -lbz2"
410 AC_LINK_IFELSE( AC_LANG_PROGRAM([[
411 #ifdef HAVE_BZLIB_H
412 #include <bzlib.h>
413 #endif]],
414 [[return (int)BZ2_bzopen("conftest", "rb");]]),
415 [AC_MSG_RESULT([yes]);HAVE_LIBBZ2=1; break;],
416 AC_MSG_RESULT([no]))
417 LIBS="$OLD_LIBS"
418
419 # Check for the availabiity of libreadline
420
421 AC_CHECK_HEADERS([readline/readline.h], [HAVE_READLINE_H=1])
422 AC_CHECK_HEADERS([readline/history.h], [HAVE_HISTORY_H=1])
423 AC_CHECK_LIB([readline], [readline], [HAVE_LIB_READLINE=1])
424
425 # This facilitates -ansi builds under Linux
426 dnl AC_DEFINE([_GNU_SOURCE], [], [Enable GNU extensions in glibc])
427
428 PCRE_STATIC_CFLAG=""
429 if test "x$enable_shared" = "xno" ; then
430 AC_DEFINE([PCRE_STATIC], [1], [
431 Define if linking statically (TODO: make nice with Libtool)])
432 PCRE_STATIC_CFLAG="-DPCRE_STATIC"
433 fi
434 AC_SUBST(PCRE_STATIC_CFLAG)
435
436 # Here is where pcre specific defines are handled
437
438 if test "$enable_utf8" = "yes"; then
439 AC_DEFINE([SUPPORT_UTF8], [], [
440 Define to enable support for the UTF-8 Unicode encoding. This will
441 work even in an EBCDIC environment, but it is incompatible with
442 the EBCDIC macro. That is, PCRE can support *either* EBCDIC code
443 *or* ASCII/UTF-8, but not both at once.])
444 fi
445
446 if test "$enable_unicode_properties" = "yes"; then
447 AC_DEFINE([SUPPORT_UCP], [], [
448 Define to enable support for Unicode properties])
449 fi
450
451 if test "$enable_stack_for_recursion" = "no"; then
452 AC_DEFINE([NO_RECURSE], [], [
453 PCRE uses recursive function calls to handle backtracking while
454 matching. This can sometimes be a problem on systems that have
455 stacks of limited size. Define NO_RECURSE to get a version that
456 doesn't use recursion in the match() function; instead it creates
457 its own stack by steam using pcre_recurse_malloc() to obtain memory
458 from the heap. For more detail, see the comments and other stuff
459 just above the match() function. On systems that support it,
460 "configure" can be used to set this in the Makefile
461 (use --disable-stack-for-recursion).])
462 fi
463
464 if test "$enable_pcregrep_libz" = "yes"; then
465 AC_DEFINE([SUPPORT_LIBZ], [], [
466 Define to allow pcregrep to be linked with libz, so that it is
467 able to handle .gz files.])
468 fi
469
470 if test "$enable_pcregrep_libbz2" = "yes"; then
471 AC_DEFINE([SUPPORT_LIBBZ2], [], [
472 Define to allow pcregrep to be linked with libbz2, so that it is
473 able to handle .bz2 files.])
474 fi
475
476 if test "$enable_pcretest_libreadline" = "yes"; then
477 AC_DEFINE([SUPPORT_LIBREADLINE], [], [
478 Define to allow pcretest to be linked with libreadline.])
479 fi
480
481 AC_DEFINE_UNQUOTED([NEWLINE], [$ac_pcre_newline_value], [
482 The value of NEWLINE determines the newline character sequence. On
483 systems that support it, "configure" can be used to override the
484 default, which is 10. The possible values are 10 (LF), 13 (CR),
485 3338 (CRLF), -1 (ANY), or -2 (ANYCRLF).])
486
487 if test "$enable_bsr_anycrlf" = "yes"; then
488 AC_DEFINE([BSR_ANYCRLF], [], [
489 By default, the \R escape sequence matches any Unicode line ending
490 character or sequence of characters. If BSR_ANYCRLF is defined, this is
491 changed so that backslash-R matches only CR, LF, or CRLF. The build-
492 time default can be overridden by the user of PCRE at runtime. On
493 systems that support it, "configure" can be used to override the
494 default.])
495 fi
496
497 AC_DEFINE_UNQUOTED([LINK_SIZE], [$with_link_size], [
498 The value of LINK_SIZE determines the number of bytes used to store
499 links as offsets within the compiled regex. The default is 2, which
500 allows for compiled patterns up to 64K long. This covers the vast
501 majority of cases. However, PCRE can also be compiled to use 3 or 4
502 bytes instead. This allows for longer patterns in extreme cases. On
503 systems that support it, "configure" can be used to override this default.])
504
505 AC_DEFINE_UNQUOTED([POSIX_MALLOC_THRESHOLD], [$with_posix_malloc_threshold], [
506 When calling PCRE via the POSIX interface, additional working storage
507 is required for holding the pointers to capturing substrings because
508 PCRE requires three integers per substring, whereas the POSIX
509 interface provides only two. If the number of expected substrings is
510 small, the wrapper function uses space on the stack, because this is
511 faster than using malloc() for each call. The threshold above which
512 the stack is no longer used is defined by POSIX_MALLOC_THRESHOLD. On
513 systems that support it, "configure" can be used to override this
514 default.])
515
516 AC_DEFINE_UNQUOTED([MATCH_LIMIT], [$with_match_limit], [
517 The value of MATCH_LIMIT determines the default number of times the
518 internal match() function can be called during a single execution of
519 pcre_exec(). There is a runtime interface for setting a different
520 limit. The limit exists in order to catch runaway regular
521 expressions that take for ever to determine that they do not match.
522 The default is set very large so that it does not accidentally catch
523 legitimate cases. On systems that support it, "configure" can be
524 used to override this default default.])
525
526 AC_DEFINE_UNQUOTED([MATCH_LIMIT_RECURSION], [$with_match_limit_recursion], [
527 The above limit applies to all calls of match(), whether or not they
528 increase the recursion depth. In some environments it is desirable
529 to limit the depth of recursive calls of match() more strictly, in
530 order to restrict the maximum amount of stack (or heap, if
531 NO_RECURSE is defined) that is used. The value of
532 MATCH_LIMIT_RECURSION applies only to recursive calls of match(). To
533 have any useful effect, it must be less than the value of
534 MATCH_LIMIT. The default is to use the same value as MATCH_LIMIT.
535 There is a runtime method for setting a different limit. On systems
536 that support it, "configure" can be used to override the default.])
537
538 AC_DEFINE([MAX_NAME_SIZE], [32], [
539 This limit is parameterized just in case anybody ever wants to
540 change it. Care must be taken if it is increased, because it guards
541 against integer overflow caused by enormously large patterns.])
542
543 AC_DEFINE([MAX_NAME_COUNT], [10000], [
544 This limit is parameterized just in case anybody ever wants to
545 change it. Care must be taken if it is increased, because it guards
546 against integer overflow caused by enormously large patterns.])
547
548 AH_VERBATIM([PCRE_EXP_DEFN], [
549 /* If you are compiling for a system other than a Unix-like system or
550 Win32, and it needs some magic to be inserted before the definition
551 of a function that is exported by the library, define this macro to
552 contain the relevant magic. If you do not define this macro, it
553 defaults to "extern" for a C compiler and "extern C" for a C++
554 compiler on non-Win32 systems. This macro apears at the start of
555 every exported function that is part of the external API. It does
556 not appear on functions that are "external" in the C sense, but
557 which are internal to the library. */
558 #undef PCRE_EXP_DEFN])
559
560 if test "$enable_ebcdic" = "yes"; then
561 AC_DEFINE_UNQUOTED([EBCDIC], [], [
562 If you are compiling for a system that uses EBCDIC instead of ASCII
563 character codes, define this macro as 1. On systems that can use
564 "configure", this can be done via --enable-ebcdic. PCRE will then
565 assume that all input strings are in EBCDIC. If you do not define
566 this macro, PCRE will assume input strings are ASCII or UTF-8 Unicode.
567 It is not possible to build a version of PCRE that supports both
568 EBCDIC and UTF-8.])
569 fi
570
571 # Platform specific issues
572 NO_UNDEFINED=
573 EXPORT_ALL_SYMBOLS=
574 case $host_os in
575 cygwin* | mingw* )
576 if test X"$enable_shared" = Xyes; then
577 NO_UNDEFINED="-no-undefined"
578 EXPORT_ALL_SYMBOLS="-Wl,--export-all-symbols"
579 fi
580 ;;
581 esac
582
583 # The extra LDFLAGS for each particular library
584 # (Note: The libpcre*_version bits are m4 variables, assigned above)
585
586 EXTRA_LIBPCRE_LDFLAGS="$EXTRA_LIBPCRE_LDFLAGS \
587 $NO_UNDEFINED -version-info libpcre_version"
588
589 EXTRA_LIBPCREPOSIX_LDFLAGS="$EXTRA_LIBPCREPOSIX_LDFLAGS \
590 $NO_UNDEFINED -version-info libpcreposix_version"
591
592 EXTRA_LIBPCRECPP_LDFLAGS="$EXTRA_LIBPCRECPP_LDFLAGS \
593 $NO_UNDEFINED -version-info libpcrecpp_version \
594 $EXPORT_ALL_SYMBOLS"
595
596 AC_SUBST(EXTRA_LIBPCRE_LDFLAGS)
597 AC_SUBST(EXTRA_LIBPCREPOSIX_LDFLAGS)
598 AC_SUBST(EXTRA_LIBPCRECPP_LDFLAGS)
599
600 # When we run 'make distcheck', use these arguments.
601 DISTCHECK_CONFIGURE_FLAGS="--enable-cpp --enable-unicode-properties"
602 AC_SUBST(DISTCHECK_CONFIGURE_FLAGS)
603
604 # Check that, if --enable-pcregrep-libz or --enable-pcregrep-libbz2 is
605 # specified, the relevant library is available.
606
607 if test "$enable_pcregrep_libz" = "yes"; then
608 if test "$HAVE_ZLIB_H" != "1"; then
609 echo "** Cannot --enable-pcregrep-libz because zlib.h was not found"
610 exit 1
611 fi
612 if test "$HAVE_LIBZ" != "1"; then
613 echo "** Cannot --enable-pcregrep-libz because libz was not found"
614 exit 1
615 fi
616 LIBZ="-lz"
617 fi
618 AC_SUBST(LIBZ)
619
620 if test "$enable_pcregrep_libbz2" = "yes"; then
621 if test "$HAVE_BZLIB_H" != "1"; then
622 echo "** Cannot --enable-pcregrep-libbz2 because bzlib.h was not found"
623 exit 1
624 fi
625 if test "$HAVE_LIBBZ2" != "1"; then
626 echo "** Cannot --enable-pcregrep-libbz2 because libbz2 was not found"
627 exit 1
628 fi
629 LIBBZ2="-lbz2"
630 fi
631 AC_SUBST(LIBBZ2)
632
633 # Similarly for --enable-pcretest-readline
634
635 if test "$enable_pcretest_libreadline" = "yes"; then
636 if test "$HAVE_READLINE_H" != "1"; then
637 echo "** Cannot --enable-pcretest-readline because readline/readline.h was not found."
638 exit 1
639 fi
640 if test "$HAVE_HISTORY_H" != "1"; then
641 echo "** Cannot --enable-pcretest-readline because readline/history.h was not found."
642 exit 1
643 fi
644 LIBREADLINE="-lreadline"
645 fi
646 AC_SUBST(LIBREADLINE)
647
648 # Produce these files, in addition to config.h.
649 AC_CONFIG_FILES(
650 Makefile
651 libpcre.pc
652 libpcreposix.pc
653 libpcrecpp.pc
654 pcre-config
655 pcre.h
656 pcre_stringpiece.h
657 pcrecpparg.h
658 )
659
660 # Make the generated script files executable.
661 AC_CONFIG_COMMANDS([script-chmod], [chmod a+x pcre-config])
662
663 # Make sure that pcre_chartables.c is removed in case the method for
664 # creating it was changed by reconfiguration.
665 AC_CONFIG_COMMANDS([delete-old-chartables], [rm -f pcre_chartables.c])
666
667 AC_OUTPUT
668
669 # Print out a nice little message after configure is run displaying your
670 # chosen options.
671
672 cat <<EOF
673
674 $PACKAGE-$VERSION configuration summary:
675
676 Install prefix .................. : ${prefix}
677 C preprocessor .................. : ${CPP}
678 C compiler ...................... : ${CC}
679 C++ preprocessor ................ : ${CXXCPP}
680 C++ compiler .................... : ${CXX}
681 Linker .......................... : ${LD}
682 C preprocessor flags ............ : ${CPPFLAGS}
683 C compiler flags ................ : ${CFLAGS}
684 C++ compiler flags .............. : ${CXXFLAGS}
685 Linker flags .................... : ${LDFLAGS}
686 Extra libraries ................. : ${LIBS}
687
688 Build C++ library ............... : ${enable_cpp}
689 Enable UTF-8 support ............ : ${enable_utf8}
690 Unicode properties .............. : ${enable_unicode_properties}
691 Newline char/sequence ........... : ${enable_newline}
692 \R matches only ANYCRLF ......... : ${enable_bsr_anycrlf}
693 EBCDIC coding ................... : ${enable_ebcdic}
694 Rebuild char tables ............. : ${enable_rebuild_chartables}
695 Use stack recursion ............. : ${enable_stack_for_recursion}
696 POSIX mem threshold ............. : ${with_posix_malloc_threshold}
697 Internal link size .............. : ${with_link_size}
698 Match limit ..................... : ${with_match_limit}
699 Match limit recursion ........... : ${with_match_limit_recursion}
700 Build shared libs ............... : ${enable_shared}
701 Build static libs ............... : ${enable_static}
702 Link pcregrep with libz ......... : ${enable_pcregrep_libz}
703 Link pcregrep with libbz2 ....... : ${enable_pcregrep_libbz2}
704 Link pcretest with libreadline .. : ${enable_pcretest_libreadline}
705
706 EOF
707
708 dnl end configure.ac

Properties

Name Value
svn:eol-style native
svn:keywords "Author Date Id Revision Url"

  ViewVC Help
Powered by ViewVC 1.1.5