/[pcre]/code/trunk/CMakeLists.txt
ViewVC logotype

Contents of /code/trunk/CMakeLists.txt

Parent Directory Parent Directory | Revision Log Revision Log


Revision 1105 - (show annotations)
Tue Oct 16 15:56:45 2012 UTC (7 years, 1 month ago) by chpe
File MIME type: text/plain
File size: 31190 byte(s)
pcre32: docs: Grammar fix
1 # CMakeLists.txt
2 #
3 #
4 # This file allows building PCRE with the CMake configuration and build
5 # tool. Download CMake in source or binary form from http://www.cmake.org/
6 #
7 # Original listfile by Christian Ehrlicher <Ch.Ehrlicher@gmx.de>
8 # Refined and expanded by Daniel Richard G. <skunk@iSKUNK.ORG>
9 # 2007-09-14 mod by Sheri so 7.4 supported configuration options can be entered
10 # 2007-09-19 Adjusted by PH to retain previous default settings
11 # 2007-12-26 (a) On UNIX, use names libpcre instead of just pcre
12 # (b) Ensure pcretest and pcregrep link with the local library,
13 # not a previously-installed one.
14 # (c) Add PCRE_SUPPORT_LIBREADLINE, PCRE_SUPPORT_LIBZ, and
15 # PCRE_SUPPORT_LIBBZ2.
16 # 2008-01-20 Brought up to date to include several new features by Christian
17 # Ehrlicher.
18 # 2008-01-22 Sheri added options for backward compatibility of library names
19 # when building with minGW:
20 # if "ON", NON_STANDARD_LIB_PREFIX causes shared libraries to
21 # be built without "lib" as prefix. (The libraries will be named
22 # pcre.dll, pcreposix.dll and pcrecpp.dll).
23 # if "ON", NON_STANDARD_LIB_SUFFIX causes shared libraries to
24 # be built with suffix of "-0.dll". (The libraries will be named
25 # libpcre-0.dll, libpcreposix-0.dll and libpcrecpp-0.dll - same names
26 # built by default with Configure and Make.
27 # 2008-01-23 PH removed the automatic build of pcredemo.
28 # 2008-04-22 PH modified READLINE support so it finds NCURSES when needed.
29 # 2008-07-03 PH updated for revised UCP property support (change of files)
30 # 2009-03-23 PH applied Steven Van Ingelgem's patch to change the name
31 # CMAKE_BINARY_DIR to PROJECT_BINARY_DIR so that it works when PCRE
32 # is included within another project.
33 # 2009-03-23 PH applied a modified version of Steven Van Ingelgem's patches to
34 # add options to stop the building of pcregrep and the tests, and
35 # to disable the final configuration report.
36 # 2009-04-11 PH applied Christian Ehrlicher's patch to show compiler flags that
37 # are set by specifying a release type.
38 # 2010-01-02 PH added test for stdint.h
39 # 2010-03-02 PH added test for inttypes.h
40 # 2011-08-01 PH added PCREGREP_BUFSIZE
41 # 2011-08-22 PH added PCRE_SUPPORT_JIT
42 # 2011-09-06 PH modified WIN32 ADD_TEST line as suggested by Sergey Cherepanov
43 # 2011-09-06 PH added PCRE_SUPPORT_PCREGREP_JIT
44 # 2011-10-04 Sheri added support for including coff data in windows shared libraries
45 # compiled with MINGW if pcre.rc and/or pcreposix.rc are placed in
46 # the source dir by the user prior to building
47 # 2011-10-04 Sheri changed various add_test's to use exes' location built instead
48 # of DEBUG location only (likely only matters in MSVC)
49 # 2011-10-04 Sheri added scripts to provide needed variables to RunTest and
50 # RunGrepTest (used for UNIX and Msys)
51 # 2011-10-04 Sheri added scripts to provide needed variables and to execute
52 # RunTest.bat in Win32 (for effortless testing with "make test")
53 # 2011-10-04 Sheri Increased minimum required cmake version
54 # 2012-01-06 PH removed pcre_info.c and added pcre_string_utils.c
55 # 2012-01-10 Zoltan Herczeg added libpcre16 support
56 # 2012-01-13 Stephen Kelly added out of source build support
57 # 2012-01-17 PH applied Stephen Kelly's patch to parse the version data out
58 # of the configure.ac file
59 # 2012-02-26 PH added support for libedit
60 # 2012-09-06 PH added support for PCRE_EBCDIC_NL25
61 # 2012-09-08 ChPe added PCRE32 support
62
63 PROJECT(PCRE C CXX)
64
65 # Increased minimum to 2.8.0 to support newer add_test features
66
67 CMAKE_MINIMUM_REQUIRED(VERSION 2.8.0)
68
69 SET(CMAKE_MODULE_PATH ${PROJECT_SOURCE_DIR}/cmake) # for FindReadline.cmake
70
71 # external packages
72 FIND_PACKAGE( BZip2 )
73 FIND_PACKAGE( ZLIB )
74 FIND_PACKAGE( Readline )
75 FIND_PACKAGE( Editline )
76
77 # Configuration checks
78
79 INCLUDE(CheckIncludeFile)
80 INCLUDE(CheckIncludeFileCXX)
81 INCLUDE(CheckFunctionExists)
82 INCLUDE(CheckTypeSize)
83
84 CHECK_INCLUDE_FILE(dirent.h HAVE_DIRENT_H)
85 CHECK_INCLUDE_FILE(stdint.h HAVE_STDINT_H)
86 CHECK_INCLUDE_FILE(inttypes.h HAVE_INTTYPES_H)
87 CHECK_INCLUDE_FILE(sys/stat.h HAVE_SYS_STAT_H)
88 CHECK_INCLUDE_FILE(sys/types.h HAVE_SYS_TYPES_H)
89 CHECK_INCLUDE_FILE(unistd.h HAVE_UNISTD_H)
90 CHECK_INCLUDE_FILE(windows.h HAVE_WINDOWS_H)
91
92 CHECK_INCLUDE_FILE_CXX(type_traits.h HAVE_TYPE_TRAITS_H)
93 CHECK_INCLUDE_FILE_CXX(bits/type_traits.h HAVE_BITS_TYPE_TRAITS_H)
94
95 CHECK_FUNCTION_EXISTS(bcopy HAVE_BCOPY)
96 CHECK_FUNCTION_EXISTS(memmove HAVE_MEMMOVE)
97 CHECK_FUNCTION_EXISTS(strerror HAVE_STRERROR)
98 CHECK_FUNCTION_EXISTS(strtoll HAVE_STRTOLL)
99 CHECK_FUNCTION_EXISTS(strtoq HAVE_STRTOQ)
100 CHECK_FUNCTION_EXISTS(_strtoi64 HAVE__STRTOI64)
101
102 CHECK_TYPE_SIZE("long long" LONG_LONG)
103 CHECK_TYPE_SIZE("unsigned long long" UNSIGNED_LONG_LONG)
104
105 # User-configurable options
106 #
107 # (Note: CMakeSetup displays these in alphabetical order, regardless of
108 # the order we use here)
109
110 SET(BUILD_SHARED_LIBS OFF CACHE BOOL
111 "Build shared libraries instead of static ones.")
112
113 OPTION(PCRE_BUILD_PCRE8 "Build 8 bit PCRE library" ON)
114
115 OPTION(PCRE_BUILD_PCRE16 "Build 16 bit PCRE library" OFF)
116
117 OPTION(PCRE_BUILD_PCRE32 "Build 32 bit PCRE library" OFF)
118
119 OPTION(PCRE_BUILD_PCRECPP "Build the PCRE C++ library (pcrecpp)." ON)
120
121 SET(PCRE_EBCDIC OFF CACHE BOOL
122 "Use EBCDIC coding instead of ASCII. (This is rarely used outside of mainframe systems.)")
123
124 SET(PCRE_EBCDIC_NL25 OFF CACHE BOOL
125 "Use 0x25 as EBCDIC NL character instead of 0x15; implies EBCDIC.")
126
127 SET(PCRE_LINK_SIZE "2" CACHE STRING
128 "Internal link size (2, 3 or 4 allowed). See LINK_SIZE in config.h.in for details.")
129
130 SET(PCRE_MATCH_LIMIT "10000000" CACHE STRING
131 "Default limit on internal looping. See MATCH_LIMIT in config.h.in for details.")
132
133 SET(PCRE_MATCH_LIMIT_RECURSION "MATCH_LIMIT" CACHE STRING
134 "Default limit on internal recursion. See MATCH_LIMIT_RECURSION in config.h.in for details.")
135
136 SET(PCREGREP_BUFSIZE "20480" CACHE STRING
137 "Buffer size parameter for pcregrep. See PCREGREP_BUFSIZE in config.h.in for details.")
138
139 SET(PCRE_NEWLINE "LF" CACHE STRING
140 "What to recognize as a newline (one of CR, LF, CRLF, ANY, ANYCRLF).")
141
142 SET(PCRE_NO_RECURSE OFF CACHE BOOL
143 "If ON, then don't use stack recursion when matching. See NO_RECURSE in config.h.in for details.")
144
145 SET(PCRE_POSIX_MALLOC_THRESHOLD "10" CACHE STRING
146 "Threshold for malloc() usage. See POSIX_MALLOC_THRESHOLD in config.h.in for details.")
147
148 SET(PCRE_SUPPORT_JIT OFF CACHE BOOL
149 "Enable support for Just-in-time compiling.")
150
151 SET(PCRE_SUPPORT_PCREGREP_JIT ON CACHE BOOL
152 "Enable use of Just-in-time compiling in pcregrep.")
153
154 SET(PCRE_SUPPORT_UTF OFF CACHE BOOL
155 "Enable support for Unicode Transformation Format (UTF-8/UTF-16/UTF-32) encoding.")
156
157 SET(PCRE_SUPPORT_UNICODE_PROPERTIES OFF CACHE BOOL
158 "Enable support for Unicode properties (if set, UTF support will be enabled as well).")
159
160 SET(PCRE_SUPPORT_BSR_ANYCRLF OFF CACHE BOOL
161 "ON=Backslash-R matches only LF CR and CRLF, OFF=Backslash-R matches all Unicode Linebreaks")
162
163 OPTION(PCRE_SHOW_REPORT "Show the final configuration report" ON)
164 OPTION(PCRE_BUILD_PCREGREP "Build pcregrep" ON)
165 OPTION(PCRE_BUILD_TESTS "Build the tests" ON)
166
167 IF (MINGW)
168 OPTION(NON_STANDARD_LIB_PREFIX
169 "ON=Shared libraries built in mingw will be named pcre.dll, etc., instead of libpcre.dll, etc."
170 OFF)
171
172 OPTION(NON_STANDARD_LIB_SUFFIX
173 "ON=Shared libraries built in mingw will be named libpcre-0.dll, etc., instead of libpcre.dll, etc."
174 OFF)
175 ENDIF(MINGW)
176
177 # bzip2 lib
178 IF(BZIP2_FOUND)
179 OPTION (PCRE_SUPPORT_LIBBZ2 "Enable support for linking pcregrep with libbz2." ON)
180 ENDIF(BZIP2_FOUND)
181 IF(PCRE_SUPPORT_LIBBZ2)
182 INCLUDE_DIRECTORIES(${BZIP2_INCLUDE_DIR})
183 ENDIF(PCRE_SUPPORT_LIBBZ2)
184
185 # zlib
186 IF(ZLIB_FOUND)
187 OPTION (PCRE_SUPPORT_LIBZ "Enable support for linking pcregrep with libz." ON)
188 ENDIF(ZLIB_FOUND)
189 IF(PCRE_SUPPORT_LIBZ)
190 INCLUDE_DIRECTORIES(${ZLIB_INCLUDE_DIR})
191 ENDIF(PCRE_SUPPORT_LIBZ)
192
193 # editline lib
194 IF(EDITLINE_FOUND)
195 OPTION (PCRE_SUPPORT_LIBEDIT "Enable support for linking pcretest with libedit." OFF)
196 ENDIF(EDITLINE_FOUND)
197 IF(PCRE_SUPPORT_LIBEDIT)
198 INCLUDE_DIRECTORIES(${EDITLINE_INCLUDE_DIR})
199 ENDIF(PCRE_SUPPORT_LIBEDIT)
200
201 # readline lib
202 IF(READLINE_FOUND)
203 OPTION (PCRE_SUPPORT_LIBREADLINE "Enable support for linking pcretest with libreadline." ON)
204 ENDIF(READLINE_FOUND)
205 IF(PCRE_SUPPORT_LIBREADLINE)
206 INCLUDE_DIRECTORIES(${READLINE_INCLUDE_DIR})
207 ENDIF(PCRE_SUPPORT_LIBREADLINE)
208
209 # Prepare build configuration
210
211 SET(pcre_have_type_traits 0)
212 SET(pcre_have_bits_type_traits 0)
213
214 IF(HAVE_TYPE_TRAITS_H)
215 SET(pcre_have_type_traits 1)
216 ENDIF(HAVE_TYPE_TRAITS_H)
217
218 IF(HAVE_BITS_TYPE_TRAITS_H)
219 SET(pcre_have_bits_type_traits 1)
220 ENDIF(HAVE_BITS_TYPE_TRAITS_H)
221
222 SET(pcre_have_long_long 0)
223 SET(pcre_have_ulong_long 0)
224
225 IF(HAVE_LONG_LONG)
226 SET(pcre_have_long_long 1)
227 ENDIF(HAVE_LONG_LONG)
228
229 IF(HAVE_UNSIGNED_LONG_LONG)
230 SET(pcre_have_ulong_long 1)
231 ENDIF(HAVE_UNSIGNED_LONG_LONG)
232
233 IF(NOT BUILD_SHARED_LIBS)
234 SET(PCRE_STATIC 1)
235 ENDIF(NOT BUILD_SHARED_LIBS)
236
237 IF(NOT PCRE_BUILD_PCRE8 AND NOT PCRE_BUILD_PCRE16 AND NOT PCRE_BUILD_PCRE32)
238 MESSAGE(FATAL_ERROR "At least one of PCRE_BUILD_PCRE8, PCRE_BUILD_PCRE16 or PCRE_BUILD_PCRE32 must be enabled")
239 ENDIF(NOT PCRE_BUILD_PCRE8 AND NOT PCRE_BUILD_PCRE16 AND NOT PCRE_BUILD_PCRE32)
240
241 IF(PCRE_BUILD_PCRE8)
242 SET(SUPPORT_PCRE8 1)
243 ENDIF(PCRE_BUILD_PCRE8)
244
245 IF(PCRE_BUILD_PCRE16)
246 SET(SUPPORT_PCRE16 1)
247 ENDIF(PCRE_BUILD_PCRE16)
248
249 IF(PCRE_BUILD_PCRE32)
250 SET(SUPPORT_PCRE32 1)
251 ENDIF(PCRE_BUILD_PCRE32)
252
253 IF(PCRE_BUILD_PCRECPP AND NOT PCRE_BUILD_PCRE8)
254 MESSAGE(STATUS "** PCRE_BUILD_PCRE8 must be enabled for the C++ library support")
255 SET(PCRE_BUILD_PCRECPP OFF)
256 ENDIF(PCRE_BUILD_PCRECPP AND NOT PCRE_BUILD_PCRE8)
257
258 IF(PCRE_BUILD_PCREGREP AND NOT PCRE_BUILD_PCRE8)
259 MESSAGE(STATUS "** PCRE_BUILD_PCRE8 must be enabled for the pcregrep program")
260 SET(PCRE_BUILD_PCREGREP OFF)
261 ENDIF(PCRE_BUILD_PCREGREP AND NOT PCRE_BUILD_PCRE8)
262
263 IF(PCRE_SUPPORT_LIBREADLINE AND PCRE_SUPPORT_LIBEDIT)
264 MESSAGE(FATAL_ERROR "Only one of libreadline or libeditline can be specified")
265 ENDIF(PCRE_SUPPORT_LIBREADLINE AND PCRE_SUPPORT_LIBEDIT)
266
267 IF(PCRE_SUPPORT_BSR_ANYCRLF)
268 SET(BSR_ANYCRLF 1)
269 ENDIF(PCRE_SUPPORT_BSR_ANYCRLF)
270
271 IF(PCRE_SUPPORT_UTF OR PCRE_SUPPORT_UNICODE_PROPERTIES)
272 SET(SUPPORT_UTF 1)
273 SET(PCRE_SUPPORT_UTF ON)
274 ENDIF(PCRE_SUPPORT_UTF OR PCRE_SUPPORT_UNICODE_PROPERTIES)
275
276 IF(PCRE_SUPPORT_UNICODE_PROPERTIES)
277 SET(SUPPORT_UCP 1)
278 ENDIF(PCRE_SUPPORT_UNICODE_PROPERTIES)
279
280 IF(PCRE_SUPPORT_JIT)
281 SET(SUPPORT_JIT 1)
282 ENDIF(PCRE_SUPPORT_JIT)
283
284 IF(PCRE_SUPPORT_PCREGREP_JIT)
285 SET(SUPPORT_PCREGREP_JIT 1)
286 ENDIF(PCRE_SUPPORT_PCREGREP_JIT)
287
288 # This next one used to contain
289 # SET(PCRETEST_LIBS ${READLINE_LIBRARY})
290 # but I was advised to add the NCURSES test as well, along with
291 # some modifications to cmake/FindReadline.cmake which should
292 # make it possible to override the default if necessary. PH
293
294 IF(PCRE_SUPPORT_LIBREADLINE)
295 SET(SUPPORT_LIBREADLINE 1)
296 SET(PCRETEST_LIBS ${READLINE_LIBRARY} ${NCURSES_LIBRARY})
297 ENDIF(PCRE_SUPPORT_LIBREADLINE)
298
299 # libedit is a plug-compatible alternative to libreadline
300
301 IF(PCRE_SUPPORT_LIBEDIT)
302 SET(SUPPORT_LIBEDIT 1)
303 SET(PCRETEST_LIBS ${EDITLINE_LIBRARY} ${NCURSES_LIBRARY})
304 ENDIF(PCRE_SUPPORT_LIBEDIT)
305
306 IF(PCRE_SUPPORT_LIBZ)
307 SET(SUPPORT_LIBZ 1)
308 SET(PCREGREP_LIBS ${PCREGREP_LIBS} ${ZLIB_LIBRARIES})
309 ENDIF(PCRE_SUPPORT_LIBZ)
310
311 IF(PCRE_SUPPORT_LIBBZ2)
312 SET(SUPPORT_LIBBZ2 1)
313 SET(PCREGREP_LIBS ${PCREGREP_LIBS} ${BZIP2_LIBRARIES})
314 ENDIF(PCRE_SUPPORT_LIBBZ2)
315
316 SET(NEWLINE "")
317
318 IF(PCRE_NEWLINE STREQUAL "LF")
319 SET(NEWLINE "10")
320 ENDIF(PCRE_NEWLINE STREQUAL "LF")
321 IF(PCRE_NEWLINE STREQUAL "CR")
322 SET(NEWLINE "13")
323 ENDIF(PCRE_NEWLINE STREQUAL "CR")
324 IF(PCRE_NEWLINE STREQUAL "CRLF")
325 SET(NEWLINE "3338")
326 ENDIF(PCRE_NEWLINE STREQUAL "CRLF")
327 IF(PCRE_NEWLINE STREQUAL "ANY")
328 SET(NEWLINE "-1")
329 ENDIF(PCRE_NEWLINE STREQUAL "ANY")
330 IF(PCRE_NEWLINE STREQUAL "ANYCRLF")
331 SET(NEWLINE "-2")
332 ENDIF(PCRE_NEWLINE STREQUAL "ANYCRLF")
333
334 IF(NEWLINE STREQUAL "")
335 MESSAGE(FATAL_ERROR "The PCRE_NEWLINE variable must be set to one of the following values: \"LF\", \"CR\", \"CRLF\", \"ANY\", \"ANYCRLF\".")
336 ENDIF(NEWLINE STREQUAL "")
337
338 IF(PCRE_EBCDIC)
339 SET(EBCDIC 1)
340 IF(PCRE_NEWLINE STREQUAL "LF")
341 SET(NEWLINE "21")
342 ENDIF(PCRE_NEWLINE STREQUAL "LF")
343 IF(PCRE_NEWLINE STREQUAL "CRLF")
344 SET(NEWLINE "3349")
345 ENDIF(PCRE_NEWLINE STREQUAL "CRLF")
346 ENDIF(PCRE_EBCDIC)
347
348 IF(PCRE_EBCDIC_NL25)
349 SET(EBCDIC 1)
350 SET(EBCDIC_NL25 1)
351 IF(PCRE_NEWLINE STREQUAL "LF")
352 SET(NEWLINE "37")
353 ENDIF(PCRE_NEWLINE STREQUAL "LF")
354 IF(PCRE_NEWLINE STREQUAL "CRLF")
355 SET(NEWLINE "3365")
356 ENDIF(PCRE_NEWLINE STREQUAL "CRLF")
357 ENDIF(PCRE_EBCDIC_NL25)
358
359 IF(PCRE_NO_RECURSE)
360 SET(NO_RECURSE 1)
361 ENDIF(PCRE_NO_RECURSE)
362
363 # Output files
364 CONFIGURE_FILE(config-cmake.h.in
365 ${PROJECT_BINARY_DIR}/config.h
366 @ONLY)
367
368 # Parse version numbers and date out of configure.ac
369
370 file(STRINGS ${PROJECT_SOURCE_DIR}/configure.ac
371 configure_lines
372 LIMIT_COUNT 50 # Read only the first 50 lines of the file
373 )
374
375 set(SEARCHED_VARIABLES "pcre_major" "pcre_minor" "pcre_prerelease" "pcre_date")
376 foreach(configure_line ${configure_lines})
377 foreach(_substitution_variable ${SEARCHED_VARIABLES})
378 string(TOUPPER ${_substitution_variable} _substitution_variable_upper)
379 if (NOT ${_substitution_variable_upper})
380 string(REGEX MATCH "m4_define\\(${_substitution_variable}, \\[(.*)\\]" MACTHED_STRING ${configure_line})
381 if (CMAKE_MATCH_1)
382 set(${_substitution_variable_upper} ${CMAKE_MATCH_1})
383 endif()
384 endif()
385 endforeach()
386 endforeach()
387
388 CONFIGURE_FILE(pcre.h.in
389 ${PROJECT_BINARY_DIR}/pcre.h
390 @ONLY)
391
392 # What about pcre-config and libpcre.pc?
393
394 IF(PCRE_BUILD_PCRECPP)
395 CONFIGURE_FILE(pcre_stringpiece.h.in
396 ${PROJECT_BINARY_DIR}/pcre_stringpiece.h
397 @ONLY)
398
399 CONFIGURE_FILE(pcrecpparg.h.in
400 ${PROJECT_BINARY_DIR}/pcrecpparg.h
401 @ONLY)
402 ENDIF(PCRE_BUILD_PCRECPP)
403
404 # Character table generation
405
406 OPTION(PCRE_REBUILD_CHARTABLES "Rebuild char tables" OFF)
407 IF(PCRE_REBUILD_CHARTABLES)
408 ADD_EXECUTABLE(dftables dftables.c)
409
410 GET_TARGET_PROPERTY(DFTABLES_EXE dftables LOCATION)
411
412 ADD_CUSTOM_COMMAND(
413 COMMENT "Generating character tables (pcre_chartables.c) for current locale"
414 DEPENDS dftables
415 COMMAND ${DFTABLES_EXE}
416 ARGS ${PROJECT_BINARY_DIR}/pcre_chartables.c
417 OUTPUT ${PROJECT_BINARY_DIR}/pcre_chartables.c
418 )
419 ELSE(PCRE_REBUILD_CHARTABLES)
420 CONFIGURE_FILE(${PROJECT_SOURCE_DIR}/pcre_chartables.c.dist
421 ${PROJECT_BINARY_DIR}/pcre_chartables.c
422 COPYONLY)
423 ENDIF(PCRE_REBUILD_CHARTABLES)
424
425 # Source code
426
427 SET(PCRE_HEADERS ${PROJECT_BINARY_DIR}/pcre.h)
428
429 IF(PCRE_BUILD_PCRE8)
430 SET(PCRE_SOURCES
431 pcre_byte_order.c
432 pcre_chartables.c
433 pcre_compile.c
434 pcre_config.c
435 pcre_dfa_exec.c
436 pcre_exec.c
437 pcre_fullinfo.c
438 pcre_get.c
439 pcre_globals.c
440 pcre_jit_compile.c
441 pcre_maketables.c
442 pcre_newline.c
443 pcre_ord2utf8.c
444 pcre_refcount.c
445 pcre_string_utils.c
446 pcre_study.c
447 pcre_tables.c
448 pcre_ucd.c
449 pcre_valid_utf8.c
450 pcre_version.c
451 pcre_xclass.c
452 )
453
454 SET(PCREPOSIX_HEADERS pcreposix.h)
455
456 SET(PCREPOSIX_SOURCES pcreposix.c)
457
458 ENDIF(PCRE_BUILD_PCRE8)
459
460 IF(PCRE_BUILD_PCRE16)
461 SET(PCRE16_SOURCES
462 pcre16_byte_order.c
463 pcre16_chartables.c
464 pcre16_compile.c
465 pcre16_config.c
466 pcre16_dfa_exec.c
467 pcre16_exec.c
468 pcre16_fullinfo.c
469 pcre16_get.c
470 pcre16_globals.c
471 pcre16_jit_compile.c
472 pcre16_maketables.c
473 pcre16_newline.c
474 pcre16_ord2utf16.c
475 pcre16_refcount.c
476 pcre16_string_utils.c
477 pcre16_study.c
478 pcre16_tables.c
479 pcre16_ucd.c
480 pcre16_utf16_utils.c
481 pcre16_valid_utf16.c
482 pcre16_version.c
483 pcre16_xclass.c
484 )
485 ENDIF(PCRE_BUILD_PCRE16)
486
487 IF(PCRE_BUILD_PCRE32)
488 SET(PCRE32_SOURCES
489 pcre32_byte_order.c
490 pcre32_chartables.c
491 pcre32_compile.c
492 pcre32_config.c
493 pcre32_dfa_exec.c
494 pcre32_exec.c
495 pcre32_fullinfo.c
496 pcre32_get.c
497 pcre32_globals.c
498 pcre32_jit_compile.c
499 pcre32_maketables.c
500 pcre32_newline.c
501 pcre32_ord2utf32.c
502 pcre32_refcount.c
503 pcre32_string_utils.c
504 pcre32_study.c
505 pcre32_tables.c
506 pcre32_ucd.c
507 pcre32_utf32_utils.c
508 pcre32_valid_utf32.c
509 pcre32_version.c
510 pcre32_xclass.c
511 )
512 ENDIF(PCRE_BUILD_PCRE32)
513
514 IF(MINGW AND NOT PCRE_STATIC)
515 IF (EXISTS ${PROJECT_SOURCE_DIR}/pcre.rc)
516 ADD_CUSTOM_COMMAND(OUTPUT ${PROJECT_SOURCE_DIR}/pcre.o
517 PRE-LINK
518 COMMAND windres ARGS pcre.rc pcre.o
519 WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
520 COMMENT Using pcre coff info in mingw build)
521 SET(PCRE_SOURCES
522 ${PCRE_SOURCES} ${PROJECT_SOURCE_DIR}/pcre.o
523 )
524 ENDIF(EXISTS ${PROJECT_SOURCE_DIR}/pcre.rc)
525 IF (EXISTS ${PROJECT_SOURCE_DIR}/pcreposix.rc)
526 ADD_CUSTOM_COMMAND(OUTPUT ${PROJECT_SOURCE_DIR}/pcreposix.o
527 PRE-LINK
528 COMMAND windres ARGS pcreposix.rc pcreposix.o
529 WORKING_DIRECTORY ${PROJECT_SOURCE_DIR}
530 COMMENT Using pcreposix coff info in mingw build)
531 SET(PCREPOSIX_SOURCES
532 ${PCREPOSIX_SOURCES} ${PROJECT_SOURCE_DIR}/pcreposix.o
533 )
534 ENDIF(EXISTS ${PROJECT_SOURCE_DIR}/pcreposix.rc)
535 ENDIF(MINGW AND NOT PCRE_STATIC)
536
537 SET(PCRECPP_HEADERS
538 pcrecpp.h
539 pcre_scanner.h
540 ${PROJECT_BINARY_DIR}/pcrecpparg.h
541 ${PROJECT_BINARY_DIR}/pcre_stringpiece.h
542 )
543
544 SET(PCRECPP_SOURCES
545 pcrecpp.cc
546 pcre_scanner.cc
547 pcre_stringpiece.cc
548 )
549
550 # Build setup
551
552 ADD_DEFINITIONS(-DHAVE_CONFIG_H)
553
554 IF(MSVC)
555 ADD_DEFINITIONS(-D_CRT_SECURE_NO_DEPRECATE)
556 ENDIF(MSVC)
557
558 SET(CMAKE_INCLUDE_CURRENT_DIR 1)
559 # needed to make sure to not link debug libs
560 # against release libs and vice versa
561 IF(WIN32)
562 SET(CMAKE_DEBUG_POSTFIX "d")
563 ENDIF(WIN32)
564
565 SET(targets)
566
567 # Libraries
568 # pcre
569 IF(PCRE_BUILD_PCRE8)
570 ADD_LIBRARY(pcre ${PCRE_HEADERS} ${PCRE_SOURCES} ${PROJECT_BINARY_DIR}/config.h)
571 SET(targets ${targets} pcre)
572 ADD_LIBRARY(pcreposix ${PCREPOSIX_HEADERS} ${PCREPOSIX_SOURCES})
573 SET(targets ${targets} pcreposix)
574 TARGET_LINK_LIBRARIES(pcreposix pcre)
575
576 IF(MINGW AND NOT PCRE_STATIC)
577 IF(NON_STANDARD_LIB_PREFIX)
578 SET_TARGET_PROPERTIES(pcre pcreposix
579 PROPERTIES PREFIX ""
580 )
581 ENDIF(NON_STANDARD_LIB_PREFIX)
582
583 IF(NON_STANDARD_LIB_SUFFIX)
584 SET_TARGET_PROPERTIES(pcre pcreposix
585 PROPERTIES SUFFIX "-0.dll"
586 )
587 ENDIF(NON_STANDARD_LIB_SUFFIX)
588 ENDIF(MINGW AND NOT PCRE_STATIC)
589
590 ENDIF(PCRE_BUILD_PCRE8)
591
592 IF(PCRE_BUILD_PCRE16)
593 ADD_LIBRARY(pcre16 ${PCRE_HEADERS} ${PCRE16_SOURCES} ${PROJECT_BINARY_DIR}/config.h)
594 SET(targets ${targets} pcre16)
595
596 IF(MINGW AND NOT PCRE_STATIC)
597 IF(NON_STANDARD_LIB_PREFIX)
598 SET_TARGET_PROPERTIES(pcre16
599 PROPERTIES PREFIX ""
600 )
601 ENDIF(NON_STANDARD_LIB_PREFIX)
602
603 IF(NON_STANDARD_LIB_SUFFIX)
604 SET_TARGET_PROPERTIES(pcre16
605 PROPERTIES SUFFIX "-0.dll"
606 )
607 ENDIF(NON_STANDARD_LIB_SUFFIX)
608 ENDIF(MINGW AND NOT PCRE_STATIC)
609
610 ENDIF(PCRE_BUILD_PCRE16)
611
612 IF(PCRE_BUILD_PCRE32)
613 ADD_LIBRARY(pcre32 ${PCRE_HEADERS} ${PCRE32_SOURCES} ${PROJECT_BINARY_DIR}/config.h)
614 SET(targets ${targets} pcre32)
615
616 IF(MINGW AND NOT PCRE_STATIC)
617 IF(NON_STANDARD_LIB_PREFIX)
618 SET_TARGET_PROPERTIES(pcre32
619 PROPERTIES PREFIX ""
620 )
621 ENDIF(NON_STANDARD_LIB_PREFIX)
622
623 IF(NON_STANDARD_LIB_SUFFIX)
624 SET_TARGET_PROPERTIES(pcre32
625 PROPERTIES SUFFIX "-0.dll"
626 )
627 ENDIF(NON_STANDARD_LIB_SUFFIX)
628 ENDIF(MINGW AND NOT PCRE_STATIC)
629
630 ENDIF(PCRE_BUILD_PCRE32)
631
632 # pcrecpp
633 IF(PCRE_BUILD_PCRECPP)
634 ADD_LIBRARY(pcrecpp ${PCRECPP_HEADERS} ${PCRECPP_SOURCES})
635 SET(targets ${targets} pcrecpp)
636 TARGET_LINK_LIBRARIES(pcrecpp pcre)
637
638 IF(MINGW AND NOT PCRE_STATIC)
639 IF(NON_STANDARD_LIB_PREFIX)
640 SET_TARGET_PROPERTIES(pcrecpp
641 PROPERTIES PREFIX ""
642 )
643 ENDIF(NON_STANDARD_LIB_PREFIX)
644
645 IF(NON_STANDARD_LIB_SUFFIX)
646 SET_TARGET_PROPERTIES(pcrecpp
647 PROPERTIES SUFFIX "-0.dll"
648 )
649 ENDIF(NON_STANDARD_LIB_SUFFIX)
650 ENDIF(MINGW AND NOT PCRE_STATIC)
651 ENDIF(PCRE_BUILD_PCRECPP)
652
653
654 # Executables
655
656 # Removed by PH (2008-01-23) because pcredemo shouldn't really be built
657 # automatically, and it gave trouble in some environments anyway.
658 # ADD_EXECUTABLE(pcredemo pcredemo.c)
659 # TARGET_LINK_LIBRARIES(pcredemo pcreposix)
660 # IF(NOT BUILD_SHARED_LIBS)
661 # # make sure to not use declspec(dllimport) in static mode on windows
662 # SET_TARGET_PROPERTIES(pcredemo PROPERTIES COMPILE_FLAGS "-DPCRE_STATIC")
663 # ENDIF(NOT BUILD_SHARED_LIBS)
664
665 IF(PCRE_BUILD_PCREGREP)
666 ADD_EXECUTABLE(pcregrep pcregrep.c)
667 SET(targets ${targets} pcregrep)
668 TARGET_LINK_LIBRARIES(pcregrep pcreposix ${PCREGREP_LIBS})
669 ENDIF(PCRE_BUILD_PCREGREP)
670
671 # Testing
672 IF(PCRE_BUILD_TESTS)
673 ENABLE_TESTING()
674
675 SET(PCRETEST_SOURCES pcretest.c)
676 IF(PCRE_BUILD_PCRE8)
677 LIST(APPEND PCRETEST_SOURCES pcre_printint.c)
678 ENDIF(PCRE_BUILD_PCRE8)
679 IF(PCRE_BUILD_PCRE16)
680 LIST(APPEND PCRETEST_SOURCES pcre16_printint.c)
681 ENDIF(PCRE_BUILD_PCRE16)
682 IF(PCRE_BUILD_PCRE32)
683 LIST(APPEND PCRETEST_SOURCES pcre32_printint.c)
684 ENDIF(PCRE_BUILD_PCRE32)
685
686 ADD_EXECUTABLE(pcretest ${PCRETEST_SOURCES})
687 SET(targets ${targets} pcretest)
688 IF(PCRE_BUILD_PCRE8)
689 LIST(APPEND PCRETEST_LIBS pcreposix pcre)
690 ENDIF(PCRE_BUILD_PCRE8)
691 IF(PCRE_BUILD_PCRE16)
692 LIST(APPEND PCRETEST_LIBS pcre16)
693 ENDIF(PCRE_BUILD_PCRE16)
694 IF(PCRE_BUILD_PCRE32)
695 LIST(APPEND PCRETEST_LIBS pcre32)
696 ENDIF(PCRE_BUILD_PCRE32)
697 TARGET_LINK_LIBRARIES(pcretest ${PCRETEST_LIBS})
698
699 IF(PCRE_SUPPORT_JIT)
700 ADD_EXECUTABLE(pcre_jit_test pcre_jit_test.c)
701 SET(targets ${targets} pcre_jit_test)
702 SET(PCRE_JIT_TEST_LIBS )
703 IF(PCRE_BUILD_PCRE8)
704 LIST(APPEND PCRE_JIT_TEST_LIBS pcre)
705 ENDIF(PCRE_BUILD_PCRE8)
706 IF(PCRE_BUILD_PCRE16)
707 LIST(APPEND PCRE_JIT_TEST_LIBS pcre16)
708 ENDIF(PCRE_BUILD_PCRE16)
709 IF(PCRE_BUILD_PCRE32)
710 LIST(APPEND PCRE_JIT_TEST_LIBS pcre32)
711 ENDIF(PCRE_BUILD_PCRE32)
712 TARGET_LINK_LIBRARIES(pcre_jit_test ${PCRE_JIT_TEST_LIBS})
713 ENDIF(PCRE_SUPPORT_JIT)
714
715 IF(PCRE_BUILD_PCRECPP)
716 ADD_EXECUTABLE(pcrecpp_unittest pcrecpp_unittest.cc)
717 SET(targets ${targets} pcrecpp_unittest)
718 TARGET_LINK_LIBRARIES(pcrecpp_unittest pcrecpp)
719 IF(MINGW AND NON_STANDARD_LIB_NAMES AND NOT PCRE_STATIC)
720 SET_TARGET_PROPERTIES(pcrecpp
721 PROPERTIES PREFIX ""
722 )
723 ENDIF(MINGW AND NON_STANDARD_LIB_NAMES AND NOT PCRE_STATIC)
724
725 ADD_EXECUTABLE(pcre_scanner_unittest pcre_scanner_unittest.cc)
726 SET(targets ${targets} pcre_scanner_unittest)
727 TARGET_LINK_LIBRARIES(pcre_scanner_unittest pcrecpp)
728
729 ADD_EXECUTABLE(pcre_stringpiece_unittest pcre_stringpiece_unittest.cc)
730 SET(targets ${targets} pcre_stringpiece_unittest)
731 TARGET_LINK_LIBRARIES(pcre_stringpiece_unittest pcrecpp)
732 ENDIF(PCRE_BUILD_PCRECPP)
733
734 # exes in Debug location tested by the RunTest shell script
735 # via "make test"
736 IF(PCRE_BUILD_PCREGREP)
737 GET_TARGET_PROPERTY(PCREGREP_EXE pcregrep DEBUG_LOCATION)
738 ENDIF(PCRE_BUILD_PCREGREP)
739
740 GET_TARGET_PROPERTY(PCRETEST_EXE pcretest DEBUG_LOCATION)
741
742 # =================================================
743 # Write out a CTest configuration file
744 #
745 FILE(WRITE ${PROJECT_BINARY_DIR}/CTestCustom.ctest
746 "# This is a generated file.
747 MESSAGE(\"When testing is complete, review test output in the
748 \\\"${PROJECT_BINARY_DIR}/Testing/Temporary\\\" folder.\")
749 MESSAGE(\" \")
750 ")
751
752 FILE(WRITE ${PROJECT_BINARY_DIR}/pcre_test.sh
753 "#! /bin/sh
754 # This is a generated file.
755 srcdir=${PROJECT_SOURCE_DIR}
756 pcretest=${PCRETEST_EXE}
757 source ${PROJECT_SOURCE_DIR}/RunTest
758 if test \"$?\" != \"0\"; then exit 1; fi
759 # End
760 ")
761
762 IF(UNIX)
763 ADD_TEST(pcre_test sh ${PROJECT_BINARY_DIR}/pcre_test.sh)
764 ENDIF(UNIX)
765
766 IF(PCRE_BUILD_PCREGREP)
767 FILE(WRITE ${PROJECT_BINARY_DIR}/pcre_grep_test.sh
768 "#! /bin/sh
769 # This is a generated file.
770 srcdir=${PROJECT_SOURCE_DIR}
771 pcregrep=${PCREGREP_EXE}
772 pcretest=${PCRETEST_EXE}
773 source ${PROJECT_SOURCE_DIR}/RunGrepTest
774 if test \"$?\" != \"0\"; then exit 1; fi
775 # End
776 ")
777
778 IF(UNIX)
779 ADD_TEST(pcre_grep_test sh ${PROJECT_BINARY_DIR}/pcre_grep_test.sh)
780 ENDIF(UNIX)
781 ENDIF(PCRE_BUILD_PCREGREP)
782
783 IF(WIN32)
784 # Provide environment for executing the bat file version of RunTest
785 FILE(TO_NATIVE_PATH ${PROJECT_SOURCE_DIR} winsrc)
786 FILE(TO_NATIVE_PATH ${PROJECT_BINARY_DIR} winbin)
787 FILE(TO_NATIVE_PATH ${PCRETEST_EXE} winexe)
788
789 FILE(WRITE ${PROJECT_BINARY_DIR}/pcre_test.bat
790 "\@REM This is a generated file.
791 \@echo off
792 setlocal
793 SET srcdir=\"${winsrc}\"
794 SET pcretest=\"${winexe}\"
795 if not [%CMAKE_CONFIG_TYPE%]==[] SET pcretest=\"${winbin}\\%CMAKE_CONFIG_TYPE%\\pcretest.exe\"
796 call %srcdir%\\RunTest.Bat
797 if errorlevel 1 exit /b 1
798 echo RunTest.bat tests successfully completed
799 ")
800
801 ADD_TEST(NAME pcre_test_bat
802 COMMAND pcre_test.bat)
803 SET_TESTS_PROPERTIES(pcre_test_bat PROPERTIES
804 PASS_REGULAR_EXPRESSION "RunTest\\.bat tests successfully completed")
805
806 IF("$ENV{OSTYPE}" STREQUAL "msys")
807 # Both the sh and bat file versions of RunTest are run if make test is used
808 # in msys
809 ADD_TEST(pcre_test_sh sh.exe ${PROJECT_BINARY_DIR}/pcre_test.sh)
810 IF(PCRE_BUILD_PCREGREP)
811 ADD_TEST(pcre_grep_test sh.exe ${PROJECT_BINARY_DIR}/pcre_grep_test.sh)
812 ENDIF(PCRE_BUILD_PCREGREP)
813 ENDIF("$ENV{OSTYPE}" STREQUAL "msys")
814
815 ENDIF(WIN32)
816
817 # Changed to accommodate testing whichever location was just built
818
819 IF(PCRE_SUPPORT_JIT)
820 ADD_TEST(pcre_jit_test pcre_jit_test)
821 ENDIF(PCRE_SUPPORT_JIT)
822
823 IF(PCRE_BUILD_PCRECPP)
824 ADD_TEST(pcrecpp_test pcrecpp_unittest)
825 ADD_TEST(pcre_scanner_test pcre_scanner_unittest)
826 ADD_TEST(pcre_stringpiece_test pcre_stringpiece_unittest)
827 ENDIF(PCRE_BUILD_PCRECPP)
828
829 ENDIF(PCRE_BUILD_TESTS)
830
831 # Installation
832 SET(CMAKE_INSTALL_ALWAYS 1)
833
834 INSTALL(TARGETS ${targets}
835 RUNTIME DESTINATION bin
836 LIBRARY DESTINATION lib
837 ARCHIVE DESTINATION lib)
838
839 INSTALL(FILES ${PCRE_HEADERS} ${PCREPOSIX_HEADERS} DESTINATION include)
840
841 FILE(GLOB html ${PROJECT_SOURCE_DIR}/doc/html/*.html)
842 FILE(GLOB man1 ${PROJECT_SOURCE_DIR}/doc/*.1)
843 FILE(GLOB man3 ${PROJECT_SOURCE_DIR}/doc/*.3)
844
845 IF(PCRE_BUILD_PCRECPP)
846 INSTALL(FILES ${PCRECPP_HEADERS} DESTINATION include)
847 ELSE(PCRE_BUILD_PCRECPP)
848 # Remove pcrecpp.3
849 FOREACH(man ${man3})
850 GET_FILENAME_COMPONENT(man_tmp ${man} NAME)
851 IF(NOT man_tmp STREQUAL "pcrecpp.3")
852 SET(man3_new ${man3} ${man})
853 ENDIF(NOT man_tmp STREQUAL "pcrecpp.3")
854 ENDFOREACH(man ${man3})
855 SET(man3 ${man3_new})
856 ENDIF(PCRE_BUILD_PCRECPP)
857
858 INSTALL(FILES ${man1} DESTINATION man/man1)
859 INSTALL(FILES ${man3} DESTINATION man/man3)
860 INSTALL(FILES ${html} DESTINATION share/doc/pcre/html)
861
862 # help, only for nice output
863 IF(BUILD_SHARED_LIBS)
864 SET(BUILD_STATIC_LIBS OFF)
865 ELSE(BUILD_SHARED_LIBS)
866 SET(BUILD_STATIC_LIBS ON)
867 ENDIF(BUILD_SHARED_LIBS)
868
869 IF(PCRE_SHOW_REPORT)
870 STRING(TOUPPER "${CMAKE_BUILD_TYPE}" buildtype)
871 IF (CMAKE_C_FLAGS)
872 SET(cfsp " ")
873 ENDIF(CMAKE_C_FLAGS)
874 IF (CMAKE_CXX_FLAGS)
875 SET(cxxfsp " ")
876 ENDIF(CMAKE_CXX_FLAGS)
877 MESSAGE(STATUS "")
878 MESSAGE(STATUS "")
879 MESSAGE(STATUS "PCRE configuration summary:")
880 MESSAGE(STATUS "")
881 MESSAGE(STATUS " Install prefix .................. : ${CMAKE_INSTALL_PREFIX}")
882 MESSAGE(STATUS " C compiler ...................... : ${CMAKE_C_COMPILER}")
883 MESSAGE(STATUS " C++ compiler .................... : ${CMAKE_CXX_COMPILER}")
884 MESSAGE(STATUS " C compiler flags ................ : ${CMAKE_C_FLAGS}${cfsp}${CMAKE_C_FLAGS_${buildtype}}")
885 MESSAGE(STATUS " C++ compiler flags .............. : ${CMAKE_CXX_FLAGS}${cxxfsp}${CMAKE_CXX_FLAGS_${buildtype}}")
886 MESSAGE(STATUS "")
887 MESSAGE(STATUS " Build 8 bit PCRE library ........ : ${PCRE_BUILD_PCRE8}")
888 MESSAGE(STATUS " Build 16 bit PCRE library ....... : ${PCRE_BUILD_PCRE16}")
889 MESSAGE(STATUS " Build 32 bit PCRE library ....... : ${PCRE_BUILD_PCRE32}")
890 MESSAGE(STATUS " Build C++ library ............... : ${PCRE_BUILD_PCRECPP}")
891 MESSAGE(STATUS " Enable JIT compiling support .... : ${PCRE_SUPPORT_JIT}")
892 MESSAGE(STATUS " Enable UTF support .............. : ${PCRE_SUPPORT_UTF}")
893 MESSAGE(STATUS " Unicode properties .............. : ${PCRE_SUPPORT_UNICODE_PROPERTIES}")
894 MESSAGE(STATUS " Newline char/sequence ........... : ${PCRE_NEWLINE}")
895 MESSAGE(STATUS " \\R matches only ANYCRLF ......... : ${PCRE_SUPPORT_BSR_ANYCRLF}")
896 MESSAGE(STATUS " EBCDIC coding ................... : ${PCRE_EBCDIC}")
897 MESSAGE(STATUS " EBCDIC coding with NL=0x25 ...... : ${PCRE_EBCDIC_NL25}")
898 MESSAGE(STATUS " Rebuild char tables ............. : ${PCRE_REBUILD_CHARTABLES}")
899 MESSAGE(STATUS " No stack recursion .............. : ${PCRE_NO_RECURSE}")
900 MESSAGE(STATUS " POSIX mem threshold ............. : ${PCRE_POSIX_MALLOC_THRESHOLD}")
901 MESSAGE(STATUS " Internal link size .............. : ${PCRE_LINK_SIZE}")
902 MESSAGE(STATUS " Match limit ..................... : ${PCRE_MATCH_LIMIT}")
903 MESSAGE(STATUS " Match limit recursion ........... : ${PCRE_MATCH_LIMIT_RECURSION}")
904 MESSAGE(STATUS " Build shared libs ............... : ${BUILD_SHARED_LIBS}")
905 MESSAGE(STATUS " Build static libs ............... : ${BUILD_STATIC_LIBS}")
906 MESSAGE(STATUS " Build pcregrep .................. : ${PCRE_BUILD_PCREGREP}")
907 MESSAGE(STATUS " Enable JIT in pcregrep .......... : ${PCRE_SUPPORT_PCREGREP_JIT}")
908 MESSAGE(STATUS " Buffer size for pcregrep ........ : ${PCREGREP_BUFSIZE}")
909 MESSAGE(STATUS " Build tests (implies pcretest .. : ${PCRE_BUILD_TESTS}")
910 MESSAGE(STATUS " and pcregrep)")
911 IF(ZLIB_FOUND)
912 MESSAGE(STATUS " Link pcregrep with libz ......... : ${PCRE_SUPPORT_LIBZ}")
913 ELSE(ZLIB_FOUND)
914 MESSAGE(STATUS " Link pcregrep with libz ......... : Library not found" )
915 ENDIF(ZLIB_FOUND)
916 IF(BZIP2_FOUND)
917 MESSAGE(STATUS " Link pcregrep with libbz2 ....... : ${PCRE_SUPPORT_LIBBZ2}")
918 ELSE(BZIP2_FOUND)
919 MESSAGE(STATUS " Link pcregrep with libbz2 ....... : Library not found" )
920 ENDIF(BZIP2_FOUND)
921 IF(EDITLINE_FOUND)
922 MESSAGE(STATUS " Link pcretest with libeditline .. : ${PCRE_SUPPORT_LIBEDIT}")
923 ELSE(EDITLINE_FOUND)
924 MESSAGE(STATUS " Link pcretest with libeditline .. : Library not found" )
925 ENDIF(EDITLINE_FOUND)
926 IF(READLINE_FOUND)
927 MESSAGE(STATUS " Link pcretest with libreadline .. : ${PCRE_SUPPORT_LIBREADLINE}")
928 ELSE(READLINE_FOUND)
929 MESSAGE(STATUS " Link pcretest with libreadline .. : Library not found" )
930 ENDIF(READLINE_FOUND)
931
932 IF(MINGW AND NOT PCRE_STATIC)
933 MESSAGE(STATUS " Non-standard dll names (prefix) . : ${NON_STANDARD_LIB_PREFIX}")
934 MESSAGE(STATUS " Non-standard dll names (suffix) . : ${NON_STANDARD_LIB_SUFFIX}")
935 ENDIF(MINGW AND NOT PCRE_STATIC)
936 MESSAGE(STATUS "")
937 ENDIF(PCRE_SHOW_REPORT)
938
939 # end CMakeLists.txt

  ViewVC Help
Powered by ViewVC 1.1.5